blob: 1d434d62d9179cfb6044371c59fef101052b1084 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..10} )
inherit bash-completion-r1 distutils-r1 optfeature
MY_PV="${PV/_beta/b}"
DESCRIPTION="Asynchronous task queue/job queue based on distributed message passing"
HOMEPAGE="
https://celeryproject.org/
https://pypi.org/project/celery/
https://github.com/celery/celery
"
SRC_URI="https://github.com/celery/celery/archive/v${MY_PV}.tar.gz -> ${P}.gh.tar.gz"
S="${WORKDIR}/${PN}-${MY_PV}"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"
IUSE="examples"
RDEPEND="
>=dev-python/billiard-3.6.4.0[${PYTHON_USEDEP}]
<dev-python/billiard-5.0.0[${PYTHON_USEDEP}]
>=dev-python/click-8.1.2[${PYTHON_USEDEP}]
<dev-python/click-9.0.0[${PYTHON_USEDEP}]
>=dev-python/click-didyoumean-0.3.0[${PYTHON_USEDEP}]
>=dev-python/click-plugins-1.1.1[${PYTHON_USEDEP}]
>=dev-python/click-repl-0.2.0[${PYTHON_USEDEP}]
>=dev-python/kombu-5.3.0_beta1[${PYTHON_USEDEP}]
<dev-python/kombu-6.0[${PYTHON_USEDEP}]
>=dev-python/pytz-2021.3[${PYTHON_USEDEP}]
>=dev-python/vine-5.0.0[${PYTHON_USEDEP}]
<dev-python/vine-6.0.0[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
$(python_gen_impl_dep 'ncurses(+)')
>=dev-python/boto3-1.9.178[${PYTHON_USEDEP}]
dev-python/cryptography[${PYTHON_USEDEP}]
dev-python/elasticsearch-py[${PYTHON_USEDEP}]
>=dev-python/moto-2.2.6[${PYTHON_USEDEP}]
dev-python/msgpack[${PYTHON_USEDEP}]
dev-python/pylibmc[${PYTHON_USEDEP}]
>=dev-python/pymongo-4.0.2[${PYTHON_USEDEP}]
dev-python/pytest-celery[${PYTHON_USEDEP}]
dev-python/pytest-click[${PYTHON_USEDEP}]
dev-python/pytest-subtests[${PYTHON_USEDEP}]
>=dev-python/pytest-timeout-1.4.2[${PYTHON_USEDEP}]
>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
dev-python/redis[${PYTHON_USEDEP}]
dev-python/sphinx-testing[${PYTHON_USEDEP}]
dev-python/tblib[${PYTHON_USEDEP}]
sci-astronomy/pyephem[${PYTHON_USEDEP}]
)
doc? (
dev-python/docutils[${PYTHON_USEDEP}]
>=dev-python/sphinx_celery-2.0.0[${PYTHON_USEDEP}]
dev-python/jinja[${PYTHON_USEDEP}]
dev-python/sqlalchemy[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
distutils_enable_sphinx docs --no-autodoc
EPYTEST_DESELECT=(
# Failing tests
t/unit/contrib/test_sphinx.py::test_sphinx
)
python_install_all() {
# Main celeryd init.d and conf.d
newinitd "${FILESDIR}/celery.initd-r2" celery
newconfd "${FILESDIR}/celery.confd-r2" celery
if use examples; then
docinto examples
dodoc -r examples/.
docompress -x "/usr/share/doc/${PF}/examples"
fi
newbashcomp extra/bash-completion/celery.bash "${PN}"
distutils-r1_python_install_all
}
pkg_postinst() {
optfeature "msgpack support" dev-python/msgpack
#optfeature "rabbitmq support" dev-python/librabbitmq
#optfeature "slmq support" dev-python/softlayer_messaging
#optfeature "couchbase support" dev-python/couchbase
optfeature "redis support" dev-python/redis
optfeature "auth support" dev-python/pyopenssl
optfeature "pyro support" dev-python/Pyro4
optfeature "yaml support" dev-python/pyyaml
optfeature "memcache support" dev-python/pylibmc
optfeature "mongodb support" dev-python/pymongo
optfeature "sqlalchemy support" dev-python/sqlalchemy
optfeature "sqs support" dev-python/boto
#optfeature "cassandra support" dev-python/cassandra-driver
}
|