blob: 4b5e7bb7c43afd67bdd38d41cd14f2812e07ec80 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Copyright 2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
DISTUTILS_OPTIONAL=1
PYTHON_COMPAT=( python3_{8..11} )
inherit cmake distutils-r1
DESCRIPTION="Library for fast text representation and classification"
HOMEPAGE="https://github.com/facebookresearch/fastText"
SRC_URI="https://github.com/facebookresearch/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="python"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
CDEPEND="dev-python/numpy[${PYTHON_USEDEP}]"
RDEPEND="python? ( ${PYTHON_DEPS}
${CDEPEND} )"
DEPEND="python? ( ${CDEPEND} )"
BDEPEND="
${DISTUTILS_DEPS}
python? ( dev-python/pybind11[${PYTHON_USEDEP}] )
"
src_prepare() {
cmake_src_prepare
use python && distutils-r1_src_prepare
sed -i -e "/CMAKE_CXX_FLAGS/d" \
-e "s/\(DESTINATION\) lib/\1 $(get_libdir)/g" \
CMakeLists.txt || die "sed failed for CMakeLists.txt"
sed -i "/extra_compile_args=/,+1d" setup.py \
|| die "sed failed for setup.py"
}
python_prepare_all() {
# fix QA
sed -i '/description/s/-/_/' setup.cfg || die "sed failed for setup.cfg"
distutils-r1_python_prepare_all
}
src_configure() {
cmake_src_configure
use python && distutils-r1_src_configure
}
src_compile() {
cmake_src_compile
use python && distutils-r1_src_compile
}
src_test() {
use python && distutils-r1_src_test
}
python_test() {
"${EPYTHON}" runtests.py -u || die "test fails"
}
src_install() {
cmake_src_install
use python && distutils-r1_src_install
find "${ED}" -name '*.a' -delete || die "find failed"
}
python_install_all() {
distutils-r1_python_install_all
find "${ED}" -type d -name "tests" -exec rm -rv {} + \
|| die "test removing failed"
}
|
