blob: 4aa226049dc932d536fa99f94d938c7a4ec63460 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Copyright 2020-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..11} )
inherit bash-completion-r1 distutils-r1 optfeature
DESCRIPTION="OCRmyPDF adds an OCR text layer to scanned PDF files"
HOMEPAGE="https://github.com/ocrmypdf/OCRmyPDF"
SRC_URI="https://github.com/ocrmypdf/OCRmyPDF/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~amd64"
RDEPEND="
>=app-text/ghostscript-gpl-9.50
>=app-text/pdfminer-20201018[${PYTHON_USEDEP}]
>=app-text/tesseract-4.1.1[jpeg,tiff,png,webp]
>=dev-python/deprecation-2.1.0[${PYTHON_USEDEP}]
>=dev-python/packaging-20[${PYTHON_USEDEP}]
>=dev-python/pikepdf-5.0.1[${PYTHON_USEDEP}]
>=dev-python/pillow-8.2.0[lcms,${PYTHON_USEDEP}]
>=dev-python/pluggy-0.13.0[${PYTHON_USEDEP}]
>=dev-python/reportlab-3.5.66[${PYTHON_USEDEP}]
>=dev-python/rich-13[${PYTHON_USEDEP}]
>=dev-python/tqdm-4[${PYTHON_USEDEP}]
>=media-gfx/img2pdf-0.3.0[${PYTHON_USEDEP}]
"
BDEPEND="
>=dev-python/setuptools-scm-7.0.5[${PYTHON_USEDEP}]
test? (
>=app-text/unpaper-6.1
>=dev-python/hypothesis-6.0.0[${PYTHON_USEDEP}]
dev-python/pytest-helpers-namespace[${PYTHON_USEDEP}]
~dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
media-libs/exempi
>=media-libs/jbig2enc-0.29
media-libs/libxmp
>=media-gfx/pngquant-2.5
)
"
distutils_enable_tests pytest
distutils_enable_sphinx docs \
dev-python/sphinx-issues \
dev-python/sphinx-rtd-theme
export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
src_prepare() {
distutils-r1_src_prepare
sed -e "/-n auto/d" -i pyproject.toml || die
}
src_install() {
distutils-r1_src_install
newbashcomp misc/completion/ocrmypdf.bash "${PN,,}"
insinto /usr/share/fish/vendor_completions.d
doins misc/completion/ocrmypdf.fish
}
pkg_postinst() {
optfeature "JBIG2 optimization support" media-libs/jbig2enc
optfeature "image cleaning support" app-text/unpaper
optfeature "PNG optimization support" media-gfx/pngquant
}
|