blob: 3adea6b6edb0eb439c489985b4499e21b6a5cf0b (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Copyright 2017-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit git-r3 cargo systemd
DESCRIPTION="Unofficial Bitwarden compatible server written in Rust"
HOMEPAGE="https://github.com/dani-garcia/vaultwarden"
EGIT_REPO_URI="https://github.com/dani-garcia/vaultwarden.git"
EGIT_COMMIT="${PV}"
SRC_URI=""
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE="mysql postgres sqlite"
REQUIRED_USE="|| ( mysql postgres sqlite )"
ACCT_DEPEND="
acct-group/vaultwarden
acct-user/vaultwarden
"
DEPEND="
${ACCT_DEPEND}
>=app-admin/vaultwarden-web-vault-2.19.0
dev-lang/rust[nightly]
dev-libs/openssl:0=
"
RDEPEND="${DEPEND}"
src_unpack() {
git-r3_src_unpack
mkdir -p "${S}" || die
pushd "${S}" > /dev/null || die
CARGO_HOME="${ECARGO_HOME}" cargo fetch || die
CARGO_HOME="${ECARGO_HOME}" cargo vendor "${ECARGO_VENDOR}" || die
popd > /dev/null || die
cargo_gen_config
}
src_configure() {
myfeatures=(
$(usev mysql)
$(usex postgres postgresql '')
$(usev sqlite)
)
}
src_compile() {
cargo_src_compile ${myfeatures:+--features "${myfeatures[*]}"} --no-default-features
}
src_install() {
cargo_src_install ${myfeatures:+--features "${myfeatures[*]}"} --no-default-features
einstalldocs
# Install init.d and conf.d scripts
newinitd "${FILESDIR}"/init vaultwarden
newconfd "${FILESDIR}"/conf vaultwarden
systemd_newunit "${FILESDIR}"/vaultwarden.service vaultwarden.service
# Install /etc/vaultwarden.env
insinto /etc
newins .env.template vaultwarden.env
fowners root:vaultwarden /etc/vaultwarden.env
fperms 640 /etc/vaultwarden.env
# Install launch wrapper
exeinto /var/lib/vaultwarden
doexe "${FILESDIR}"/vaultwarden
# Keep data dir
keepdir /var/lib/vaultwarden/data
fowners vaultwarden:vaultwarden /var/lib/vaultwarden/data
fperms 700 /var/lib/vaultwarden/data
}
src_test() {
cargo_src_test ${myfeatures:+--features "${myfeatures[*]}"} --no-default-features
}
|