1 files changed, 47 insertions, 0 deletions
diff --git a/dev-lua/resty-lrucache/resty-lrucache-0.13.ebuild b/dev-lua/resty-lrucache/resty-lrucache-0.13.ebuild
new file mode 100644
index 0000000..a7059b7
--- /dev/null
+++ b/dev-lua/resty-lrucache/resty-lrucache-0.13.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( luajit )
+
+inherit lua
+
+DESCRIPTION="A simple LRU cache for OpenResty and the ngx_lua module (based on LuaJIT FFI)"
+HOMEPAGE="https://github.com/openresty/lua-resty-lrucache"
+
+if [[ "${PV}" =~ 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/openresty/lua-resty-lrucache"
+else
+	SRC_URI="https://github.com/openresty/lua-resty-lrucache/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/lua-${P}"
+	KEYWORDS="~amd64 ~arm ~x86"
+	# TODO: arm64 and others
+fi
+
+LICENSE="BSD"
+SLOT="0"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+IUSE="+lua_targets_luajit"
+
+RDEPEND="
+	${LUA_DEPS}
+	www-servers/nginx:*[nginx_modules_http_lua]
+"
+DEPEND="
+	${RDEPEND}
+"
+
+each_lua_install() {
+	insinto "$(lua_get_lmod_dir)"
+	doins -r lib/resty
+}
+
+src_compile() { :; }
+
+src_install() {
+	lua_foreach_impl each_lua_install
+	einstalldocs
+}