Initial ebuild for dev-python/channels-redis

3 files changed, 89 insertions, 0 deletions

diff --git a/dev-python/channels-redis/Manifest b/dev-python/channels-redis/Manifest
new file mode 100644
index 0000000..d3f8b38
--- /dev/null
+++ b/dev-python/channels-redis/Manifest
@@ -0,0 +1,3 @@
+DIST channels-redis-4.0.0.gh.tar.gz 27781 BLAKE2B 20fe5d8d742ce2986d6598116bf86a06f89bcdd3840be6e8b3df4af2c53b881fd8560dbdee9d9a9f871c4b3ced3f797472bf42e23219b404d6d7362e85ca0e2d SHA512 1be61a52c750e5d0fa76e2cfb51942de12f92d9ae518bcf7aa83a796f685b75d0b4ca1c056239e77267b39570b877b686b12f78acc6aed7a557e081f98be9eb3
+EBUILD channels-redis-4.0.0.ebuild 1697 BLAKE2B 19220156013abc2658736c40a802549cebb94907b9731b51a80ada4dea6164d7af6210c2faae73066db4cbd8349eb3b1fc1f53df217147073be9763b7762767b SHA512 b2858ab862dbc61fec345037dc7f1be54e3e57c728ea3e7960da72b0af11729f43d397001e10bd279bbf840e777f83299977d199f23365812dfecc4e6c6629ef
+MISC metadata.xml 462 BLAKE2B f20c8915f4deeef22958c25161423491978a0d2615f72084b7e528aa26ebc57f4fa1dd831bea0275d54f3050576a598e9355132fe562d648b290dab416ced58f SHA512 d1c57ef70042b2f5b49936e3dc6c232e9026cd241cfaf079393f91121678b351663e7af7ed6ce912807973ac1dfba9554085b176de2c40dc14b521a1d68d122f
diff --git a/dev-python/channels-redis/channels-redis-4.0.0.ebuild b/dev-python/channels-redis/channels-redis-4.0.0.ebuild
new file mode 100644
index 0000000..952034e
--- /dev/null
+++ b/dev-python/channels-redis/channels-redis-4.0.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+MY_P=${P/-/_}
+DESCRIPTION="Provides Django Channels channel layers that use Redis as a backing store."
+HOMEPAGE="https://github.com/django/channels_redis"
+SRC_URI="https://github.com/django/${PN/-/_}/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+RDEPEND="
+	dev-python/channels[${PYTHON_USEDEP}]
+	>=dev-python/django-3.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-db/redis
+		dev-python/async-timeout[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-1.3.0[${PYTHON_USEDEP}]
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		>=dev-python/redis-py-4.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( README.rst )
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Hangs
+	tests/test_core.py::test_message_expiry__group_send__one_channel_expires_message
+	# Fails with: TypeError: int() argument must be a string, a bytes-like object or a real number, not 'NoneType'
+	tests/test_core.py::test_receive_cancel
+)
+
+python_prepare_all() {
+	# Remove sentinel tests
+	rm tests/test{_pubsub,}_sentinel.py
+
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+
+	einfo "Spawning Redis"
+	einfo "NOTE: Port ${redis_port} must be free"
+	"${EPREFIX}"/usr/sbin/redis-server - <<-EOF || die
+		daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1
+	EOF
+
+	# Run the tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}
diff --git a/dev-python/channels-redis/metadata.xml b/dev-python/channels-redis/metadata.xml
new file mode 100644
index 0000000..e4f79bf
--- /dev/null
+++ b/dev-python/channels-redis/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>marcin.deranek@slonko.net</email>
+		<name>Marcin Deranek</name>
+	</maintainer>
+	<upstream>
+		<bugs-to>https://github.com/django/channels_redis/issues</bugs-to>
+		<remote-id type="github">django/channels_redis</remote-id>
+		<remote-id type="pypi">channels-redis</remote-id>
+	</upstream>
+</pkgmetadata>