www-apps/paperless-ngx go back to 2.3.3

2 files changed, 180 insertions, 1 deletions

diff --git a/www-apps/paperless-ngx/Manifest b/www-apps/paperless-ngx/Manifest
index 2da02ad..84878db 100644
--- a/www-apps/paperless-ngx/Manifest
+++ b/www-apps/paperless-ngx/Manifest
@@ -7,5 +7,5 @@ AUX paperless.tmpfiles 349 BLAKE2B 4a59f0a0c6a4abad23cba01e216909f45a7064e93911b
 DIST paperless-ngx-v1.17.4.tar.xz 16507140 BLAKE2B 34e67810dc9264cfcfec5a62557f5c102aedb82d8f31b27302e01675b84cb39cb22925339263cd8908e828d91b3469895732962e50c2b6bc62d266222b3072c4 SHA512 eb225244d51db0ba0db9fca259825ab542448f5f9904d2bf55ad581f16a9386696457593df2ad5eda6df5eefb296f0ee0c0f27e6fc0eff8956807aedf20e0094
 DIST paperless-ngx-v2.3.3.tar.xz 60972356 BLAKE2B 46c54dd687163264270972b250ecc661cb39f672c95c19450ffc7ef457b682ec630d9ab1bf1e1a32914ead89c301e466af457ba22c09d18b214b1db9c1f470fb SHA512 40f70c734509049dd7e7842d095c8c034124b5e7e465ef88cc60b7f384e106a4ef202dd7bb5828a48ba70f2b5877196f3bf32ee998dd00407378914991c0fec8
 EBUILD paperless-ngx-1.17.4.ebuild 4839 BLAKE2B dce1e94ef73e45b7496f42629dc020686b3b852e455a6016f64c2581d211fe9d3a5e2a9cf194a4388bfa4b3325a552524c5bb22add9fee7f6454961f9f9d2709 SHA512 e490f7d9c90ee6d9064e7d569293c3ae5549e0fadd056944fcdd47deb48260eed8d39ff5e9867f06c86e7ef22fbf00191016f9cb516419b1568a816a55635495
-EBUILD paperless-ngx-2.3.3.ebuild 6086 BLAKE2B d8724620d2b2ab3e572449eff63bb100de0f61b4c2d3d119e0598133bee2dc7aea17bc2924f4f3fb6e2e4a7b34bd529d15d9ccb357a4de8df3df40461361fb42 SHA512 df99e491abd8a8280f7f9f20decd1ff20e27e01766f52d41a7a2fa87b482c10a3573533050f455dfa56df4eb97d176b9e981ee49e0fe46515aa93f2e379d3bff
+EBUILD paperless-ngx-2.3.3.ebuild 6086 BLAKE2B fb04ac94c43791d750d49a3ab549a298906def0254857e9097a2fa6d7cda42bf40e119ef7c2c4e5da295fdcf0ec0ae606a1be5b9f3b88d76b2dae42631b5dc48 SHA512 40381469b556d0729382ef7656b338e928d17ea331ead08c7f373f225a64c31a3c4e6ddb4eed02d0353f810e2d891bfd7e56c30f78241693b4359cbcf7f87779
 MISC metadata.xml 851 BLAKE2B dfb395b418d92c0c7318c4862dfbce74a312222b3a2848334806c2f8063bb63947a4c0315c289f1db83987d5e7649483efb484944afd6963b3f74c1a488877f5 SHA512 e7622cfe74bee71e3698241cb234221d9d40c9a41eca4f8b3e5e3c7338940652f5c5652cd72a675339cc6620d777e858fe5310f29cf7f87f5585eb8742b58405
diff --git a/www-apps/paperless-ngx/paperless-ngx-2.3.3.ebuild b/www-apps/paperless-ngx/paperless-ngx-2.3.3.ebuild
new file mode 100644
index 0000000..34f9c29
--- /dev/null
+++ b/www-apps/paperless-ngx/paperless-ngx-2.3.3.ebuild
@@ -0,0 +1,179 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit python-single-r1 systemd
+
+DESCRIPTION="Community supported paperless: scan, index and archive your physical documents"
+HOMEPAGE="https://github.com/paperless-ngx/paperless-ngx"
+SRC_URI="https://github.com/paperless-ngx/paperless-ngx/releases/download/v${PV}/paperless-ngx-v${PV}.tar.xz"
+S="${WORKDIR}/${PN}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="audit compression mysql +ocr postgres remote-redis +sqlite zxing"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	|| ( mysql postgres sqlite )
+"
+
+ACCT_DEPEND="
+	acct-group/paperless
+	acct-user/paperless
+"
+EXTRA_DEPEND="
+	app-text/unpaper
+	dev-python/hiredis
+	dev-python/websockets
+"
+
+DEPEND="
+	${ACCT_DEPEND}
+	${EXTRA_DEPEND}
+	${PYTHON_DEPS}
+	app-text/poppler[utils]
+	$(python_gen_cond_dep '
+		dev-python/asgiref[${PYTHON_USEDEP}]
+		dev-python/bleach[${PYTHON_USEDEP}]
+		dev-python/celery[${PYTHON_USEDEP}]
+		>=dev-python/channels-4.0[${PYTHON_USEDEP}]
+		>=dev-python/channels-redis-4.0[${PYTHON_USEDEP}]
+		dev-python/concurrent-log-handler[${PYTHON_USEDEP}]
+		>=dev-python/dateparser-1.2[${PYTHON_USEDEP}]
+		>=dev-python/django-4.2.8[${PYTHON_USEDEP}]
+		<dev-python/django-5.0[${PYTHON_USEDEP}]
+		dev-python/django-celery-results[${PYTHON_USEDEP}]
+		dev-python/django-cors-headers[${PYTHON_USEDEP}]
+		dev-python/django-extensions[${PYTHON_USEDEP}]
+		>=dev-python/django-filter-23.5[${PYTHON_USEDEP}]
+		dev-python/django-guardian[${PYTHON_USEDEP}]
+		dev-python/django-multiselectfield[${PYTHON_USEDEP}]
+		dev-python/django-redis[${PYTHON_USEDEP}]
+		>=dev-python/djangorestframework-3.14[${PYTHON_USEDEP}]
+		dev-python/djangorestframework-guardian[${PYTHON_USEDEP}]
+		dev-python/drf-writable-nested[${PYTHON_USEDEP}]
+		dev-python/filelock[${PYTHON_USEDEP}]
+		dev-python/imap-tools[${PYTHON_USEDEP}]
+		>=dev-python/inotifyrecursive-0.3[${PYTHON_USEDEP}]
+		dev-python/langdetect[${PYTHON_USEDEP}]
+		dev-python/nltk[${PYTHON_USEDEP}]
+		dev-python/pathvalidate[${PYTHON_USEDEP}]
+		dev-python/pdf2image[${PYTHON_USEDEP}]
+		dev-python/pikepdf[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		dev-python/python-dotenv[${PYTHON_USEDEP}]
+		dev-python/python-gnupg[${PYTHON_USEDEP}]
+		>=dev-python/python-ipware-2.0.0[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/pyzbar[${PYTHON_USEDEP}]
+		dev-python/rapidfuzz[${PYTHON_USEDEP}]
+		dev-python/redis[${PYTHON_USEDEP}]
+		dev-python/tqdm[${PYTHON_USEDEP}]
+		dev-python/uvicorn[${PYTHON_USEDEP}]
+		>=dev-python/watchdog-3.0[${PYTHON_USEDEP}]
+		>=dev-python/whitenoise-6.6[${PYTHON_USEDEP}]
+		>=dev-python/whoosh-2.7[${PYTHON_USEDEP}]')
+	media-gfx/imagemagick
+	media-gfx/optipng
+	media-libs/jbig2enc
+	>=sci-libs/scikit-learn-1.3
+	www-servers/gunicorn
+	audit? ( $(python_gen_cond_dep '
+		dev-python/django-auditlog[${PYTHON_USEDEP}]') )
+	compression? ( $(python_gen_cond_dep '
+		dev-python/django-compression-middleware[${PYTHON_USEDEP}]') )
+	mysql? ( dev-python/mysqlclient )
+	ocr? ( >=app-text/OCRmyPDF-15.4 )
+	postgres? ( dev-python/psycopg:2 )
+	!remote-redis? ( dev-db/redis )
+	zxing? ( media-libs/zxing-cpp[python,${PYTHON_SINGLE_USEDEP}] )
+"
+RDEPEND="${DEPEND}"
+# dev-python/tika
+# dev-python/gotenberg-client
+
+DOCS=( docker/imagemagick-policy.xml )
+
+src_prepare() {
+	default
+
+	sed \
+		-e "s|#PAPERLESS_CONSUMPTION_DIR=../consume|PAPERLESS_CONSUMPTION_DIR=/var/lib/paperless/consume|" \
+		-e "s|#PAPERLESS_DATA_DIR=../data|PAPERLESS_DATA_DIR=/var/lib/paperless/data|" \
+		-e "s|#PAPERLESS_MEDIA_ROOT=../media|PAPERLESS_MEDIA_ROOT=/var/lib/paperless/media|" \
+		-e "s|#PAPERLESS_STATICDIR=../static|PAPERLESS_STATICDIR=/usr/share/paperless/static|" \
+		-e "s|#PAPERLESS_CONVERT_TMPDIR=/var/tmp/paperless|PAPERLESS_CONVERT_TMPDIR=/var/lib/paperless/tmp|" \
+		-i "paperless.conf" || die "Cannot update paperless.conf"
+
+	cat >> "paperless.conf" <<- EOF
+
+	# Custom
+	PAPERLESS_ENABLE_COMPRESSION=$(use compression && echo true || echo false)
+	PAPERLESS_AUDIT_LOG_ENABLED=$(use audit && echo true || echo false)
+	EOF
+}
+
+src_install() {
+	einstalldocs
+
+	# Install service files
+	systemd_newunit "${FILESDIR}"/paperless-webserver.service paperless-webserver.service
+	systemd_newunit "${FILESDIR}"/paperless-scheduler.service paperless-scheduler.service
+	systemd_newunit "${FILESDIR}"/paperless-consumer.service paperless-consumer.service
+	systemd_newunit "${FILESDIR}"/paperless-task-queue.service paperless-task-queue.service
+	systemd_newunit "${FILESDIR}"/paperless.target paperless.target
+	if use remote-redis; then
+		sed -e '/redis\.service/d' -i *.service "${D}$(systemd_get_systemunitdir)"/*.service
+	fi
+
+	# Install paperless files
+	insinto /usr/share/paperless
+	doins -r docs src static gunicorn.conf.py requirements.txt
+
+	insinto /etc
+	doins paperless.conf
+	fowners root:paperless /etc/paperless.conf
+	fperms 640 /etc/paperless.conf
+
+	insinto /usr/lib/tmpfiles.d
+	doins "${FILESDIR}"/paperless.tmpfiles
+	fperms 644 /usr/lib/tmpfiles.d/paperless.tmpfiles
+
+	# Set directories
+	for dir in consume data media tmp; do
+		keepdir /var/lib/paperless/${dir}
+		fowners paperless:paperless /var/lib/paperless/${dir}
+		case "${dir}" in
+		data) fperms 700 /var/lib/paperless/${dir} ;;
+		*)    fperms 750 /var/lib/paperless/${dir} ;;
+		esac
+	done
+
+	# Main executable
+	fperms 755 "/usr/share/paperless/src/manage.py"
+	dosym -r "/usr/share/paperless/src/manage.py" "/usr/bin/paperless-manage"
+}
+
+pkg_postinst() {
+	elog "To complete the installation of paperless, edit /etc/paperless.conf file and"
+	elog "* Create the database with"
+	elog ""
+	elog "sudo -u paperless paperless-manage migrate"
+	elog ""
+	elog "* Create a super user account with"
+	elog ""
+	elog "sudo -u paperless paperless-manage createsuperuser"
+	elog ""
+	elog "After each update of paperless, you should run migration with"
+	elog ""
+	elog "sudo -u paperless paperless-manage migrate"
+	elog ""
+	elog "Paperless services can be started together with"
+	elog ""
+	elog "sudo systemctl start paperless.target"
+}