blob: c0cb3602d3be8cd63526a603f01dd06521630ad1 (
plain) (
tree)
|
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit pax-utils toolchain-funcs versionator git-r3
#MY_PV="$(get_version_component_range 1-4)"
#MY_PV="${MY_PV/_beta/-beta}"
MY_PV="2.1.0-beta3"
DESCRIPTION="Just-In-Time Compiler for the Lua programming language"
HOMEPAGE="http://luajit.org/"
SRC_URI=""
EGIT_REPO_URI="https://luajit.org/git/luajit-2.0.git"
EGIT_BRANCH="v2.1"
LICENSE="MIT"
# this should probably be pkgmoved to 2.0 for sake of consistency.
SLOT="2"
KEYWORDS=""
IUSE="lua52compat static-libs"
_emake() {
emake \
Q= \
PREFIX="${EPREFIX}/usr" \
MULTILIB="$(get_libdir)" \
DESTDIR="${D}" \
HOST_CC="$(tc-getBUILD_CC)" \
STATIC_CC="$(tc-getCC)" \
DYNAMIC_CC="$(tc-getCC) -fPIC" \
TARGET_LD="$(tc-getCC)" \
TARGET_AR="$(tc-getAR) rcus" \
BUILDMODE="$(usex static-libs mixed dynamic)" \
TARGET_STRIP="true" \
INSTALL_LIB="${ED%/}/usr/$(get_libdir)" \
"$@"
}
src_compile() {
_emake XCFLAGS="$(usex lua52compat "-DLUAJIT_ENABLE_LUA52COMPAT" "")"
}
src_install(){
_emake install
dosym "${PN}-${MY_PV}" "/usr/bin/${PN}"
pax-mark m "${ED}usr/bin/luajit-${MY_PV}"
HTML_DOCS="doc/." einstalldocs
}
|