0ad game

5 files changed, 287 insertions, 0 deletions

diff --git a/games-strategy/0ad-data/0ad-data-0.0.19_alpha.ebuild b/games-strategy/0ad-data/0ad-data-0.0.19_alpha.ebuild
new file mode 100644
index 0000000..051308e
--- /dev/null
+++ b/games-strategy/0ad-data/0ad-data-0.0.19_alpha.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit games
+
+MY_P=0ad-${PV/_/-}
+DESCRIPTION="Data files for 0ad"
+HOMEPAGE="http://wildfiregames.com/0ad/"
+SRC_URI="mirror://sourceforge/zero-ad/${MY_P}-unix-data.tar.xz"
+
+LICENSE="GPL-2 CC-BY-SA-3.0 LPPL-1.3c BitstreamVera"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	rm binaries/data/tools/fontbuilder/fonts/*.txt
+}
+
+src_install() {
+	insinto "${GAMES_DATADIR}"/0ad
+	doins -r binaries/data/*
+	prepgamesdirs
+}
diff --git a/games-strategy/0ad-data/Manifest b/games-strategy/0ad-data/Manifest
new file mode 100644
index 0000000..ab9c562
--- /dev/null
+++ b/games-strategy/0ad-data/Manifest
@@ -0,0 +1,2 @@
+DIST 0ad-0.0.19-alpha-unix-data.tar.xz 573111260 SHA256 9353f554e94adf66d69e33950f7f2515cfe308eca2c0ad381c6f39f1ad378038 SHA512 b932614b675007d18b22fbeec9f4f0d3a78b0c892e24ab7661e903b400d1299c6ea35b8cdc15bf3ac03bad108a07f03b070a3b1fd20eec6160b1074f64761eb9 WHIRLPOOL a69a62427c56b60884084a2c145e1a0baf30f94859e9bbbc9915f939ef392de678bcccd30461e02ed6ba44cdb2aa11fec53e32649b4c1c85ddd1200c85488372
+EBUILD 0ad-data-0.0.19_alpha.ebuild 570 SHA256 5ee2e4d995dd47d7200e007884b28721f3c9d3ae7389617980b1d28761be7d8e SHA512 42de34cd1d26bdeccc3f4299937c669e089176414d0a0b2870150c22e9fe86970ce569577d956dafeaaa965a1fbd5001c857433b8090373311f18cb78a75e411 WHIRLPOOL 61ccc5277f7e16e45cc783660cd002639d55becad4647d0bfb23cc87cdd331aa01848404dd4ad67bdae0f920c08c580f89c4be452c7865ace9fd255f535160d7
diff --git a/games-strategy/0ad/0ad-0.0.19_alpha.ebuild b/games-strategy/0ad/0ad-0.0.19_alpha.ebuild
new file mode 100644
index 0000000..8bad6e2
--- /dev/null
+++ b/games-strategy/0ad/0ad-0.0.19_alpha.ebuild
@@ -0,0 +1,152 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+WX_GTK_VER="3.0"
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads,ssl"
+
+inherit eutils wxwidgets toolchain-funcs gnome2-utils python-any-r1 games
+
+MY_P=0ad-${PV/_/-}
+DESCRIPTION="A free, real-time strategy game"
+HOMEPAGE="http://play0ad.com/"
+SRC_URI="mirror://sourceforge/zero-ad/${MY_P}-unix-build.tar.xz"
+
+LICENSE="GPL-2 LGPL-2.1 MIT CC-BY-SA-3.0 ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="editor +lobby nvtt pch sound test"
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/boost
+	dev-libs/icu:=
+	dev-libs/libxml2
+	dev-libs/nspr
+	~games-strategy/0ad-data-${PV}
+	media-libs/libpng:0
+	media-libs/libsdl2[X,opengl,video]
+	net-libs/enet:1.3
+	net-libs/miniupnpc:=
+	net-misc/curl
+	sys-libs/zlib
+	virtual/jpeg:0
+	virtual/opengl
+	x11-libs/libX11
+	x11-libs/libXcursor
+	editor? ( x11-libs/wxGTK:${WX_GTK_VER}[X,opengl] )
+	lobby? ( net-libs/gloox )
+	nvtt? ( media-gfx/nvidia-texture-tools )
+	sound? ( media-libs/libvorbis
+		media-libs/openal )"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	test? ( dev-lang/perl )"
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	games_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-gentoo.patch
+}
+
+src_configure() {
+	local myconf=(
+		--with-system-nvtt
+		--with-system-miniupnpc
+		--minimal-flags
+		$(usex nvtt "" "--without-nvtt")
+		$(usex pch "" "--without-pch")
+		$(usex test "" "--without-tests")
+		$(usex sound "" "--without-audio")
+		$(usex editor "--atlas" "")
+		$(usex lobby "" "--without-lobby")
+		--collada
+		--bindir="${GAMES_BINDIR}"
+		--libdir="$(games_get_libdir)"/${PN}
+		--datadir="${GAMES_DATADIR}"/${PN}
+		)
+
+	# stock premake4 does not work, use the shipped one
+	emake -C "${S}"/build/premake/premake4/build/gmake.unix
+
+	# regenerate scripts.c so our patch applies
+	cd "${S}"/build/premake/premake4 || die
+	"${S}"/build/premake/premake4/bin/release/premake4 embed || die
+
+	# rebuild premake again... this is the most stupid build system
+	emake -C "${S}"/build/premake/premake4/build/gmake.unix clean
+	emake -C "${S}"/build/premake/premake4/build/gmake.unix
+
+	# run premake to create build scripts
+	cd "${S}"/build/premake || die
+	"${S}"/build/premake/premake4/bin/release/premake4 \
+		--file="premake4.lua" \
+		--outpath="../workspaces/gcc/" \
+		--platform=$(usex amd64 "x64" "x32") \
+		--os=linux \
+		"${myconf[@]}" \
+		gmake || die "Premake failed"
+}
+
+src_compile() {
+	tc-export AR
+
+	# build bundled and patched spidermonkey
+	cd libraries/source/spidermonkey || die
+	JOBS="${MAKEOPTS}" ./build.sh || die
+	cd "${S}" || die
+
+	# build 3rd party fcollada
+	emake -C libraries/source/fcollada/src
+
+	# build 0ad
+	emake -C build/workspaces/gcc verbose=1
+}
+
+src_test() {
+	cd binaries/system || die
+	./test -libdir "${S}/binaries/system" || die "test phase failed"
+}
+
+src_install() {
+	newgamesbin binaries/system/pyrogenesis 0ad
+	use editor && newgamesbin binaries/system/ActorEditor 0ad-ActorEditor
+
+	insinto "${GAMES_DATADIR}"/${PN}
+	doins -r binaries/data/l10n
+
+	exeinto "$(games_get_libdir)"/${PN}
+	doexe binaries/system/libCollada.so
+	doexe libraries/source/spidermonkey/lib/*.so
+	use editor && doexe binaries/system/libAtlasUI.so
+
+	dodoc binaries/system/readme.txt
+	doicon -s 128 build/resources/${PN}.png
+	make_desktop_entry ${PN}
+
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/games-strategy/0ad/Manifest b/games-strategy/0ad/Manifest
new file mode 100644
index 0000000..5bbda40
--- /dev/null
+++ b/games-strategy/0ad/Manifest
@@ -0,0 +1,3 @@
+AUX 0ad-0.0.19_alpha-gentoo.patch 4144 SHA256 05c9a95d72854acef8b6e591f2976c7bdee944f30aa1fbd47f0b1bfeacd58bd5 SHA512 984b5e4911e4fe2115b116b1e20a6c33d41ff868dfb61ad6998330c47f3ad7b1cdcdfea1ea3b8cab5b8489d77741126516e13e162727aba4565848a764226979 WHIRLPOOL 5cae7a059ddc78508c86b4dcdd3e505738f233e9b06277ab5c3fc4ffd5a56f4af5fed6611243da201b36645a375a9109bb8050b0042ad802de0f2d00c7c0ed44
+DIST 0ad-0.0.19-alpha-unix-build.tar.xz 26192128 SHA256 2d43262bbcedbfa19eee23b0e78ae20fc9e0b8f4589855fca95d9908c6839bb3 SHA512 36a9e70b7c584a35a1bafddd9b6e9738e41629b0ac275e71442b934f89b3a0fb0ce535ccca4393ad90fd1313df0360c145115cbc60057b60604818242f9e9852 WHIRLPOOL 11ff3e864c480f623a06f308df0bde8d1993517ebb3e094ed85b26a142d3f55caac2dcac4750afcae973b85422b4a931f30fa1fc2aea35a0ec0378dc1cddd434
+EBUILD 0ad-0.0.19_alpha.ebuild 3512 SHA256 d3cc6bb935f42819e15d958cfe0697da4bb347db63123a0b749f45b74b16d2fb SHA512 490927245eb0416fdb7d36dc6edcfe4c294442a56e4287d3364427bec7f3fb5ac00bd684b905ac8f515fe557838437a4e402be523d64cebe0fcad5d340eed094 WHIRLPOOL 238b3a79a3cd518217632fb19f3a921451737569639a0000e133a359182dc708cf8d0defc574f71a3b7cd9f0145a84bc04cf4b8866955b8fa40d09b4f8ed4e2f
diff --git a/games-strategy/0ad/files/0ad-0.0.19_alpha-gentoo.patch b/games-strategy/0ad/files/0ad-0.0.19_alpha-gentoo.patch
new file mode 100644
index 0000000..5c48ec8
--- /dev/null
+++ b/games-strategy/0ad/files/0ad-0.0.19_alpha-gentoo.patch
@@ -0,0 +1,101 @@
+From: Julian Ospald <hasufell@gentoo.org>
+Date: Sun Jun 24 18:32:38 UTC 2012
+Subject: build system
+
+* respect flags
+* disable debug build of spidermonkey
+
+--- libraries/source/fcollada/src/Makefile
++++ libraries/source/fcollada/src/Makefile
+@@ -9,9 +9,9 @@
+ 
+ CXX ?= g++
+ CXXFLAGS += -fvisibility=hidden -W -Wall -Wno-unused-parameter -Wno-unused-function $(OS_DEFINE) $(PIC_FLAGS) $(CPPFLAGS)
+-CXXFLAGS_DEBUG := -O0 -g -D_DEBUG -DRETAIL
+-CXXFLAGS_RELEASE := -O2 -DNDEBUG -DRETAIL
+-CXXFLAGS_TEST := -O0 -g -D_DEBUG
++CXXFLAGS_DEBUG := -D_DEBUG -DRETAIL
++CXXFLAGS_RELEASE := -DNDEBUG -DRETAIL
++CXXFLAGS_TEST := -D_DEBUG
+ LIBS += `pkg-config libxml-2.0 --libs`
+ INCLUDES += -IFCollada `pkg-config libxml-2.0 --cflags`
+ INCLUDES_TEST := -IFCollada/FColladaTest $(INCLUDES)
+--- build/premake/premake4/src/tools/gcc.lua
++++ build/premake/premake4/src/tools/gcc.lua
+@@ -136,8 +136,6 @@
+ 		if not cfg.flags.Symbols then
+ 			if cfg.system == "macosx" then
+ 				table.insert(result, "-Wl,-x")
+-			else
+-				table.insert(result, "-s")
+ 			end
+ 		end
+ 	
+--- build/premake/premake4/build/gmake.unix/Premake4.make
++++ build/premake/premake4/build/gmake.unix/Premake4.make
+@@ -26,9 +26,9 @@
+   DEFINES   += -DNDEBUG -DLUA_USE_POSIX -DLUA_USE_DLOPEN
+   INCLUDES  += -I../../src/host/lua-5.1.4/src
+   CPPFLAGS  += -MMD -MP $(DEFINES) $(INCLUDES)
+-  CFLAGS    += $(CPPFLAGS) -Wall -Os
+-  CXXFLAGS  += $(CPPFLAGS) -Wall -Os
+-  LDFLAGS   += -s -rdynamic
++  CFLAGS    += $(CPPFLAGS) -Wall
++  CXXFLAGS  += $(CPPFLAGS) -Wall
++  LDFLAGS   += -rdynamic
+   LIBS      += -lm -ldl 
+   RESFLAGS  += $(DEFINES) $(INCLUDES) 
+   LDDEPS    += 
+@@ -48,8 +48,8 @@
+   DEFINES   += -D_DEBUG -DLUA_USE_POSIX -DLUA_USE_DLOPEN
+   INCLUDES  += -I../../src/host/lua-5.1.4/src
+   CPPFLAGS  += -MMD -MP $(DEFINES) $(INCLUDES)
+-  CFLAGS    += $(CPPFLAGS) -Wall -g
+-  CXXFLAGS  += $(CPPFLAGS) -Wall -g
++  CFLAGS    += $(CPPFLAGS) -Wall
++  CXXFLAGS  += $(CPPFLAGS) -Wall
+   LDFLAGS   += -rdynamic
+   LIBS      += -lm -ldl 
+   RESFLAGS  += $(DEFINES) $(INCLUDES) 
+@@ -302,4 +302,4 @@
+ 	$(SILENT) $(CC) $(PCHINCLUDES) $(CFLAGS) -MF $(OBJDIR)/lauxlib.d -MT "$@" -o "$@" -c "$<"

+ 

+ -include $(OBJECTS:%.o=%.d)

+--include $(GCH:%.h.gch=%.h.d)
+\ No newline at end of file
++-include $(GCH:%.h.gch=%.h.d)
+--- libraries/source/spidermonkey/build.sh
++++ libraries/source/spidermonkey/build.sh
+@@ -92,19 +92,7 @@
+ cd mozjs31/js/src
+ 
+ # Clean up data generated by previous builds that could cause problems
+-rm -rf build-debug
+ rm -rf build-release
+-
+-# We want separate debug/release versions of the library, so we have to change
+-# the LIBRARY_NAME for each build.
+-# (We use perl instead of sed so that it works with MozillaBuild on Windows,
+-# which has an ancient sed.)
+-perl -i.bak -pe 's/(LIBRARY_NAME\s+=).*/$1 '\''mozjs31-ps-debug'\''/' moz.build
+-mkdir -p build-debug
+-cd build-debug
+-CXXFLAGS="${TLCXXFLAGS}" ../configure ${CONF_OPTS} --with-nspr-libs="$NSPR_LIBS" --with-nspr-cflags="$NSPR_INCLUDES" --enable-debug --disable-optimize --enable-js-diagnostics --enable-gczeal # --enable-root-analysis
+-${MAKE} ${MAKE_OPTS}
+-cd ..
+ 
+ perl -i.bak -pe 's/(LIBRARY_NAME\s+=).*/$1 '\''mozjs31-ps-release'\''/' moz.build
+ mkdir -p build-release
+@@ -147,12 +135,9 @@
+ mkdir -p ${INCLUDE_DIR_DEBUG}
+ mkdir -p ${INCLUDE_DIR_RELEASE}
+ cp -R -L mozjs31/js/src/build-release/dist/include/* ${INCLUDE_DIR_RELEASE}/
+-cp -R -L mozjs31/js/src/build-debug/dist/include/* ${INCLUDE_DIR_DEBUG}/
+ 
+ mkdir -p lib/
+-cp -L mozjs31/js/src/build-debug/dist/lib/${LIB_PREFIX}mozjs31-ps-debug${LIB_SRC_SUFFIX} lib/${LIB_PREFIX}mozjs31-ps-debug${LIB_DST_SUFFIX}
+ cp -L mozjs31/js/src/build-release/dist/lib/${LIB_PREFIX}mozjs31-ps-release${LIB_SRC_SUFFIX} lib/${LIB_PREFIX}mozjs31-ps-release${LIB_DST_SUFFIX}
+-cp -L mozjs31/js/src/build-debug/dist/bin/${LIB_PREFIX}mozjs31-ps-debug${DLL_SRC_SUFFIX} ../../../binaries/system/${LIB_PREFIX}mozjs31-ps-debug${DLL_DST_SUFFIX}
+ cp -L mozjs31/js/src/build-release/dist/bin/${LIB_PREFIX}mozjs31-ps-release${DLL_SRC_SUFFIX} ../../../binaries/system/${LIB_PREFIX}mozjs31-ps-release${DLL_DST_SUFFIX}
+ 
+ # Flag that it's already been built successfully so we can skip it next time