From 4e6fdec9f62693ec38ef5ff91d59c81fec4e87f5 Mon Sep 17 00:00:00 2001
From: Marcin Deranek <marcin.deranek@booking.com>
Date: Sun, 23 Apr 2023 19:50:41 +0200
Subject: New ebuilds

---
 dev-util/scanmem/scanmem-9999.ebuild | 74 ++++++++++++++++++++++++++++++++++++
 1 file changed, 74 insertions(+)
 create mode 100644 dev-util/scanmem/scanmem-9999.ebuild

(limited to 'dev-util/scanmem/scanmem-9999.ebuild')

diff --git a/dev-util/scanmem/scanmem-9999.ebuild b/dev-util/scanmem/scanmem-9999.ebuild
new file mode 100644
index 0000000..6b9e429
--- /dev/null
+++ b/dev-util/scanmem/scanmem-9999.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit autotools python-single-r1 xdg-utils
+
+DESCRIPTION="Locate and modify variables in executing processes"
+HOMEPAGE="https://github.com/scanmem/scanmem"
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+	S="${WORKDIR}/${P}"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~riscv ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="gui static-libs"
+
+DEPEND="sys-libs/readline:="
+RDEPEND="${DEPEND}
+	gui? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3
+		sys-auth/polkit
+	)"
+
+REQUIRED_USE="gui? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use gui && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	sed -i "/CFLAGS/d" Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-readline
+		$(use_enable gui)
+		$(use_enable static-libs static)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	if use gui ; then
+		docinto gui
+		dodoc gui/{README,TODO}
+		python_fix_shebang "${ED}"
+	fi
+
+	find "${ED}" -type f -name "*.la" -delete || die
+}
+
+pkg_postinst() {
+	use gui && xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	use gui && xdg_icon_cache_update
+}
-- 
cgit v1.2.3