From 7762b829daea0d961bddf3857564f29435a899a8 Mon Sep 17 00:00:00 2001
From: Marcin Deranek <marcin.deranek@slonko.net>
Date: Tue, 5 Dec 2023 01:05:24 +0100
Subject: Initial ebuild for dev-python/django-auditlog

---
 dev-python/django-auditlog/Manifest                |  3 ++
 .../django-auditlog/django-auditlog-2.3.0.ebuild   | 52 ++++++++++++++++++++++
 dev-python/django-auditlog/metadata.xml            | 13 ++++++
 3 files changed, 68 insertions(+)
 create mode 100644 dev-python/django-auditlog/Manifest
 create mode 100644 dev-python/django-auditlog/django-auditlog-2.3.0.ebuild
 create mode 100644 dev-python/django-auditlog/metadata.xml

(limited to 'dev-python')

diff --git a/dev-python/django-auditlog/Manifest b/dev-python/django-auditlog/Manifest
new file mode 100644
index 0000000..630cdb3
--- /dev/null
+++ b/dev-python/django-auditlog/Manifest
@@ -0,0 +1,3 @@
+DIST django-auditlog-2.3.0.gh.tar.gz 47920 BLAKE2B b3f883ea2f277414b66b99fe5b5da3c16739120d0e0897ebfa2c6c716678db0653b5403069cb055d670bfcb6e810643e3e1785de2a5986dec20233b08fab58e6 SHA512 0185ef32bf595ffb1c2f5a001a4aba67c5cdf9af117d83adb58d346ab017624ed1d9d3b9e1c4f56a76d6e06b6119088ca29b0abc881714bfd6cb622da415f05a
+EBUILD django-auditlog-2.3.0.ebuild 1303 BLAKE2B eff6c66d9dd958a38d970fe716671c41f9fc7b4334445c8d3e7244e92aca6a937823783cf899be0d2188e7e75b184ef8e0c662e649476b5a1b95a99d1ae9dba4 SHA512 6db89f36769cd1e38153b1475ab2feb2b98f951f6921c3a8c8246c1de7f4fca2bfbf333eadd3d06183c70d4913dc8d8b6ad4480c3088ddef7720b252486e5213
+MISC metadata.xml 470 BLAKE2B d6ad94843286b28950e759ffa62fec40042ceb08d00cf3a9cb90f3056c330f5e1a7a31d01aff111dcc5149f8410bc145c2a56e170867ff9f5b878881fc8821ad SHA512 7f70d6df09e358e7ae71dbeb1726b1587e756864c1ff357187642539ec75f18412f7c1664425f62c830d14915776779f0e5c18fa4cd16e042651e399f681a57f
diff --git a/dev-python/django-auditlog/django-auditlog-2.3.0.ebuild b/dev-python/django-auditlog/django-auditlog-2.3.0.ebuild
new file mode 100644
index 0000000..642b5ce
--- /dev/null
+++ b/dev-python/django-auditlog/django-auditlog-2.3.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Audit log app for Django"
+HOMEPAGE="https://github.com/jazzband/django-auditlog"
+SRC_URI="https://github.com/jazzband/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RDEPEND="dev-python/django[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/psycopg:2[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-db/postgresql[server]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+	)
+"
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+distutils_enable_sphinx docs/source \
+	dev-python/sphinx-rtd-theme
+
+python_test() {
+	local db="${T}/pgsql"
+
+	initdb --username=postgres -D "${db}" || die
+	pg_ctl -w -D "${db}" start \
+		-o "-h '127.0.0.1' -p 5432 -k '${T}'" || die
+	psql -h "${T}" -U postgres -d postgres \
+		-c "ALTER ROLE postgres WITH PASSWORD '';" || die
+	createdb -h "${T}" -U postgres auditlog || die
+
+	"${EPYTHON}" -m django test -v2 --settings=auditlog_tests.test_settings || die "Tests fail with ${EPYTHON}"
+
+	pg_ctl -w -D "${db}" stop || die
+}
diff --git a/dev-python/django-auditlog/metadata.xml b/dev-python/django-auditlog/metadata.xml
new file mode 100644
index 0000000..72a85ca
--- /dev/null
+++ b/dev-python/django-auditlog/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>marcin.deranek@slonko.net</email>
+		<name>Marcin Deranek</name>
+	</maintainer>
+	<upstream>
+		<bugs-to>https://github.com/jazzband/django-auditlog/issues</bugs-to>
+		<remote-id type="github">jazzband/django-auditlog</remote-id>
+		<remote-id type="pypi">django-auditlog</remote-id>
+	</upstream>
+</pkgmetadata>
-- 
cgit v1.2.3