From e1092697bb96afe6859db264e702515dc88d68eb Mon Sep 17 00:00:00 2001
From: Marcin Deranek <marcin.deranek@booking.com>
Date: Sun, 28 May 2023 00:06:46 +0200
Subject: Initial ebuild dev-python/kombu

---
 dev-python/kombu/Manifest               |  2 +
 dev-python/kombu/kombu-5.3.0_rc1.ebuild | 82 +++++++++++++++++++++++++++++++++
 2 files changed, 84 insertions(+)
 create mode 100644 dev-python/kombu/Manifest
 create mode 100644 dev-python/kombu/kombu-5.3.0_rc1.ebuild

(limited to 'dev-python/kombu')

diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
new file mode 100644
index 0000000..2b389d1
--- /dev/null
+++ b/dev-python/kombu/Manifest
@@ -0,0 +1,2 @@
+DIST kombu-5.3.0rc1.tar.gz 434080 BLAKE2B 35cad5a8d03507f8c9c45bac68e7b840a28cb4859a1bd8c163b1668cc87ab4e33a51660ceb1e0cc375657da3373633f8d2bb0cc7b4f5a58da079b87ac561fdc5 SHA512 4960833fedaeed07998caef244e54b98b9e27850073d2428595f578354a141f5be7fb8d3ae587cc99a325743527e0b9b23a9f931b1aaa7c7d98e4216da577c33
+EBUILD kombu-5.3.0_rc1.ebuild 2189 BLAKE2B bd95c8289294dd30d616ac8f8a6f9fd1e73dc881253be5484eae0750e71081053339099760e036d7b35303e87e359964a09b03f62cbc4a07b238a39950f59752 SHA512 38830c7516f4cfdcf1042db3add897950e65060adad7e42dd6b61968cb29eb3c17a24fe3233999323ae91bc43dda7d89d56d700b9c924e4a3fb83342648ce976
diff --git a/dev-python/kombu/kombu-5.3.0_rc1.ebuild b/dev-python/kombu/kombu-5.3.0_rc1.ebuild
new file mode 100644
index 0000000..53ba0b0
--- /dev/null
+++ b/dev-python/kombu/kombu-5.3.0_rc1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="
+	https://github.com/celery/kombu/
+	https://pypi.org/project/kombu/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/py-amqp-5.1.1[${PYTHON_USEDEP}]
+	<dev-python/py-amqp-6.0.0[${PYTHON_USEDEP}]
+	dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		>=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		>=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
+		dev-python/pytest-freezegun[${PYTHON_USEDEP}]
+		dev-python/zstandard[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+		>=dev-python/redis-4.2.2[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx-celery
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		t/unit/transport/test_redis.py::test_Channel::test_connparams_health_check_interval_supported
+	)
+	local EPYTEST_IGNORE=(
+		# obsolete Pyro4
+		t/unit/transport/test_pyro.py
+		# unpackaged azure
+		t/unit/transport/test_azurestoragequeues.py
+	)
+
+	epytest
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+	optfeature "Etcd backend" dev-python/python-etcd
+	optfeature "MongoDB backend" dev-python/pymongo
+	optfeature "Redis backend" dev-python/redis
+	optfeature "sqlalchemy backend" dev-python/sqlalchemy
+	optfeature "yaml backend" dev-python/pyyaml
+	optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+	optfeature "brotli compression" "app-arch/brotli[python]"
+	optfeature "zstd compression" dev-python/zstandard
+}
-- 
cgit v1.2.3