From 83f6900e276d5c80dfb3f6ae913552108ca6665b Mon Sep 17 00:00:00 2001
From: Marcin Deranek <marcin.deranek@slonko.net>
Date: Thu, 29 Feb 2024 21:53:29 +0100
Subject: sci-libs/scikit-learn Initial build

---
 sci-libs/scikit-learn/Manifest                     |  2 +
 sci-libs/scikit-learn/scikit-learn-1.4.1_p1.ebuild | 66 ++++++++++++++++++++++
 2 files changed, 68 insertions(+)
 create mode 100644 sci-libs/scikit-learn/Manifest
 create mode 100644 sci-libs/scikit-learn/scikit-learn-1.4.1_p1.ebuild

diff --git a/sci-libs/scikit-learn/Manifest b/sci-libs/scikit-learn/Manifest
new file mode 100644
index 0000000..60404ce
--- /dev/null
+++ b/sci-libs/scikit-learn/Manifest
@@ -0,0 +1,2 @@
+DIST scikit-learn-1.4.1_p1.gh.tar.gz 7886860 BLAKE2B d383553e312859e9ec4e79bf92cd087d54cc46e4c9b6692bd18596fbd3d4c0e07ad01a286b9a482002655ce77aca68b1b1fadc28089eeb97d3efb11f60c6836a SHA512 544709d7f7c877c71de49c55ce5d677e68a05b2b0dd5364d29dde1a42bc9a4ecc0ef13e984a33bf202df6353dd34047416f803573be571c82ebd05c30f1d4c7a
+EBUILD scikit-learn-1.4.1_p1.ebuild 1686 BLAKE2B c28a3319cf349e676d74bbd64b2fed69b2dc447c0a6770aaccdd067ad8703574c9e250c8c557fa432311055aae6ef5b2caf5635ecc24ac13915c358d0e4946df SHA512 b513534f6a4ad3a046410ca511f47d1d21bbb9f528dac3f298a54460777dca129723cb1d37090e6969ef1145bcf55268930d1cadbd712909efdf5b34e24a9433
diff --git a/sci-libs/scikit-learn/scikit-learn-1.4.1_p1.ebuild b/sci-libs/scikit-learn/scikit-learn-1.4.1_p1.ebuild
new file mode 100644
index 0000000..223d0e7
--- /dev/null
+++ b/sci-libs/scikit-learn/scikit-learn-1.4.1_p1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PV=${PV/_p/.post}
+MY_P="${PN}-${MY_PV}"
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Machine learning library for Python"
+HOMEPAGE="https://scikit-learn.org/stable/"
+SRC_URI="https://github.com/scikit-learn/scikit-learn/archive/${MY_PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 ~ppc64 ~riscv ~x86 ~arm64-macos ~x64-macos"
+IUSE="examples"
+
+S="${WORKDIR}/${MY_P}"
+
+DEPEND="
+	virtual/blas:=
+	virtual/cblas:=
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/wheel[${PYTHON_USEDEP}]
+	>=dev-python/joblib-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.25[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/threadpoolctl-2.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pythran-0.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cython-3.0.8[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+# For some reason this wants to use urllib to fetch things from the internet
+# distutils_enable_sphinx doc \
+# 	dev-python/matplotlib \
+# 	dev-python/memory-profiler \
+# 	dev-python/numpydoc \
+# 	dev-python/pandas \
+# 	dev-python/pillow \
+# 	dev-python/seaborn \
+# 	dev-python/sphinx-gallery \
+# 	dev-python/sphinx-prompt \
+# 	dev-python/scikit-image
+
+python_test() {
+	# This needs to be run in the install dir
+	cd "${WORKDIR}/${MY_P}-${EPYTHON//./_}/install/usr/lib/${EPYTHON}/site-packages/sklearn" || die
+	distutils-r1_python_test
+}
+
+python_install_all() {
+	find "${S}" -name \*LICENSE.txt -delete || die
+	distutils-r1_python_install_all
+	use examples && dodoc -r examples
+}
-- 
cgit v1.2.3